Build weather station

Placed on 2019-04-30

API key
An API key is required to obtain weather information. For this you need to register an account with OpenWeatherMap, which can be done here: https://home.openweathermap.org/users/sign_up. After you are registered, go to the "API keys" section. Copy the API key you find there (See photos).

Go to "API keys"

Copy the API key

Install the ArduinoJson library
If you already have the latest version of the ArduinoJson library, you can skip this step.
Open the Arduino IDE, go to Sketch > Include library > Manage libraries (see photo). Search for "arduinojson" and install the latest version of Benoit Blanchon's ArduinoJson library (see photo).

Open the library manager

Download the ArduinoJson library

Install the LiquidCrystal I2C library
First, download the library ZIP file by going to this link: https://github.com/johnrickman/LiquidCrystal_I2C/archive/master.zip.
Then go to Sketch -> Include Library -> Add .ZIP library in the Arduino IDE and select the ZIP file of the library.

Add the ZIP file

Install the ESP8266 boards
If you have already added the ESP8266 boards to the Arduino IDE, you can skip this step.
Open the Arduino IDE settings by going to File > Preferences. In the "Additional Boards Manager URLs" text box, enter the URL "http://arduino.esp8266.com/stable/package_esp8266com_index.json" (see photo). Then open the Board Manager with Tools > Board > Boards Manager (see photo). Then install the ESP8266 boards (see photo).

Change the "Additional Boards Manager URLs"

Open the Board Manager

Install the ESP8266 boards

Find out I2C address
Before uploading the weather station code, you need to find the address of the I2C LCD module. To do this, use the code below.

I2C scanner code

#include <Wire.h>
 
 
void setup()
{
  Wire.begin();
 
  Serial.begin(9600);
  Serial.println("\nI2C Scanner");
}
 
 
void loop()
{
  byte error, address;
  int nDevices;
 
  Serial.println("Scanning...");
 
  nDevices = 0;
  for(address = 1; address < 127; address++ )
  {
    Wire.beginTransmission(address);
    error = Wire.endTransmission();
 
    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16)
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");
 
      nDevices++;
    }
    else if (error==4)
    {
      Serial.print("Unknown error at address 0x");
      if (address<16)
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");
 
  delay(5000);
}

In this case the address is 0x3F

Upload code
Make sure you have selected the correct board under Tools -> Board and that you have selected the correct port under Tools -> Port.
Enter your information and upload the following code to the Wemos via the Arduino IDE:

Weerstation code

#include <ESP8266WiFi.h>
#include <ArduinoJson.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <WiFiUdp.h>

char ssid[] = "--VOER HIER DE NAAM VAN JE WIFI NETWERK IN--";
char pass[] = "--VOER HIER HET WACHTWOORD VAN JE WIFI NETWERK IN--";
String apiKey = "--VOER HIER JE API KEY IN--";
String city = "--VOER HIER DE NAAM VAN JE STAD OF DORP IN--";
int timeOffset = 7200; // 7200 voor zomertijd, 3600 voor wintertijd
int address = 0x3F; // Voer hier het I2C adres in van de vorige stap

// Ik raad aan niks onder deze regel te wijzigigen.

WiFiClient client;
LiquidCrystal_I2C lcd(address, 16, 2);
char servername[] = "api.openweathermap.org";
String result;
unsigned long weatherLast = millis();
unsigned long weatherInterval = 60000;

char ntpServer[] = "0.nl.pool.ntp.org";
WiFiUDP UDP;
IPAddress timeServerIP;
const int NTP_PACKET_SIZE = 48;
byte ntpBuffer[NTP_PACKET_SIZE];
uint32_t unixTime = 0;
unsigned long lastActualTime = 0;

void setup() {
  lcd.begin();
  lcd.backlight();
  lcd.noCursor();
  lcd.clear();
  lcd.print("Laden (WiFi)...");
  
  Serial.begin(9600);
  WiFi.begin(ssid, pass);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
  }
  
  lcd.clear();
  lcd.print("Laden (NTP)...");

  UDP.begin(123);
  if(!WiFi.hostByName(ntpServer, timeServerIP)) {
   lcd.clear();
   lcd.print("NTP DNS fail");
   Serial.println("DNS lookup fail. Rebooting.");
   delay(1000); // Wacht even met rebooten
   ESP.reset();
  }
  sendNTPpacket(timeServerIP);

  /* Deze loop wacht op een NTP response */
  while(true) {
    uint32_t time = getTime();
    if(time) {
      unixTime = time;
      ntpLast = millis();
      break;
    }
  }

  lcd.clear();
  lcd.print("Laden (Data)...");
  getWeather();
}

void loop() {
  unsigned long currentMillis = millis();

  uint32_t actualTime = unixTime + (currentMillis - ntpLast) / 1000;
  if(lastActualTime - actualTime > 1000) {
    lastActualTime = actualTime;

    int hours = getHours(actualTime);
    int minutes = getMinutes(actualTime);
    int seconds = getSeconds(actualTime);
    lcd.setCursor(0, 0);
    if(hours < 10) {
      lcd.print("0");
    }
    lcd.print(hours);
    lcd.print(":");
    if(minutes < 10) {
      lcd.print("0");
    }
    lcd.print(minutes);
    lcd.print(":");
    if(seconds < 10) {
      lcd.print("0");
    }
    lcd.print(seconds);
  }

  if(currentMillis - weatherLast > weatherInterval) {
    getWeather();
  }
}

void getWeather() {
  if(!client.connect(servername, 80)) {
      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Verbinding");
      lcd.setCursor(0, 1);
      lcd.print("mislukt");
      Serial.println("Connection failed");
      weatherLast = millis();
      return;
   }

   client.println("GET /data/2.5/weather?q=" + city + "&APPID=" + apiKey + "&units=metric");
   client.println("Host: api.openweathermap.org");
   client.println("Connection: close");
   if(client.println() == 0) {
     lcd.clear();
     lcd.setCursor(0, 0);
     lcd.print("Kon request");
     lcd.setCursor(0, 1);
     lcd.print("niet sturen");
     Serial.println("Failed to send request");
     weatherLast = millis();
     return;
   }

   const size_t capacity = JSON_ARRAY_SIZE(3) + 2*JSON_OBJECT_SIZE(1) + JSON_OBJECT_SIZE(2) + 3*JSON_OBJECT_SIZE(4) + JSON_OBJECT_SIZE(5) + JSON_OBJECT_SIZE(6) + JSON_OBJECT_SIZE(12) + 340;
   DynamicJsonDocument doc(capacity);

   DeserializationError error = deserializeJson(doc, client);
   if (error) {
     lcd.clear();
     lcd.setCursor(0, 0);
     lcd.print("Kon JSON");
     lcd.setCursor(0, 1);
     lcd.print("niet verwerken");
     Serial.print("deserializeJson() failed: ");
     Serial.println(error.c_str());
     weatherLast = millis();
     return;
   }

   long temp = doc["main"]["temp"].as<double>();
   long humidity = doc["main"]["humidity"].as<long>();

   lcd.clear();
   lcd.setCursor(0, 1);
   lcd.print(temp);
   lcd.print("C | ");
   lcd.print(humidity);
   lcd.print("%");

   Serial.print("Temperature: ");
   Serial.print(temp);
   Serial.println(" C");
   Serial.print("Humidity: ");
   Serial.print(humidity);
   Serial.println("%");

   client.stop();
   weatherLast = millis();
}

uint32_t getTime() {
  if (UDP.parsePacket() == 0) {
    return 0;
  }
  UDP.read(ntpBuffer, NTP_PACKET_SIZE);
  uint32_t ntpTime = (ntpBuffer[40] << 24) | (ntpBuffer[41] << 16) | (ntpBuffer[42] << 8) | ntpBuffer[43];
  const uint32_t seventyYears = 2208988800UL;
  uint32_t unixTime = ntpTime - seventyYears;
  return unixTime + timeOffset;
}

void sendNTPpacket(IPAddress& address) {
  memset(ntpBuffer, 0, NTP_PACKET_SIZE);
  ntpBuffer[0] = 0b11100011;
  UDP.beginPacket(address, 123);
  UDP.write(ntpBuffer, NTP_PACKET_SIZE);
  UDP.endPacket();
}

inline int getSeconds(uint32_t unixTime) {
  return unixTime % 60;
}

inline int getMinutes(uint32_t unixTime) {
  return unixTime / 60 % 60;
}

inline int getHours(uint32_t unixTime) {
  return unixTime / 3600 % 24;
}

Previous page 2. Hardware Current Page 3. Software Next page 4. Result 1. Introduction 2. Hardware 3. Software 4. Result Posted by Melluh Website I am a software developer, but I am also very interested in electronics.

Build weather station

I2C scanner code

Weerstation code

Comments