Build your own Bluetooth news ticker

Placed on 2017-11-13

Example news ticker

Supplies

Arduino Uno R3 - clone In stock Or an Arduino Nano € 11,50 MAX7219 4x Dot matrix module In stock This is the display, you need at least 1, 2 is even better! € 10,20 HC-06 Bluetooth module met adapter In stock This is the HC-06 Bluetooth Slave, you need 1 € 8,50 5.6KΩ Metal film resistor 1 / 4W - 100 pieces Out of stock The voltage divider for the Bluetooth module € 1,45 10KΩ Metal film resitor 1/4W - 10 pieces In stock The voltage divider for the Bluetooth module € 1,75 Mean Well SGA12E09-P1J power supply - 9V 1,33A In stock For extra power, USB cannot supply enough € 14,00 DC socket built-in 5.5 mm x 2.1 mm - 5 pieces Out of stock € 2,50 Total € 49,90

The schedule:

The schematic shows how everything should be connected. If you already get a spinning feeling from all those wires, don't look too much at the whole, but try to consider and connect the modules one by one. You'll see that it's not too bad.

The schematic shows only one quadruple dot matrix LED module, in reality you can link two together for a double width!

Message board connection diagram

The bluetooth module does require a little extra attention. The Bluetooth communication signals (TX and RX) work at 3.3 volts, while the Arduino works with 5 volts. The two resistors will reduce the 5 volts from Arduino to about 3.3 volts.

The nutrition:
You can see that a 5 volt power supply is used. You have to. An Arduino connected to USB cannot supply enough current to power the LED matrix, especially with a double matrix.

Arduino Library and Sketch:

The Arduino sketch uses two external libraries, to install these, search for MD_MAX72xx in the library manager. Then install MD_Max72xx and MD_Parola

Ticker USB Arduino Library

Set the right module:
After installing the libraries, we need to tell the MD_Max72xx library which led matrix module we are using.

Locate the file on your hard drive: MD_MAX72xx.h
(probably in the folder C:\Users\your name\Documents\ Arduino \libraries\MD_MAX72XX\src\)

//Op regel 214, zie je staan:   
#define   USE_PAROLA_HW   1, verander die 1 in 0

//Op regel 237 zie je staan: 
#define   USE_FC16_HW   0,   verander die 0 in 1.

The Arduino Sketch:

Then we can now load the sketch.
Copy the sketch and paste the code into the Arduino software, select the correct com port and type Arduino and press upload!

#include <MD_Parola.h>
#include <MD_MAX72xx.h>
#include <SPI.h>
#include <SoftwareSerial.h>
#include <EEPROM.h>
#define MAX_DEVICES 8
#define CLK_PIN   13
#define DATA_PIN  11
#define CS_PIN    10

// Use softserial for the bluetooth module
SoftwareSerial mySerial(2, 3);

// HARDWARE SPI
MD_Parola LK = MD_Parola(CS_PIN, MAX_DEVICES);

uint8_t scrollSpeed = 30;    // default frame delay value
textEffect_t scrollEffect = PA_SCROLL_LEFT;
textPosition_t scrollAlign = PA_LEFT;
uint16_t scrollPause = 2000; // in milliseconds

// Global message buffers shared by Serial and Scrolling functions
#define  BUF_SIZE  75
char curMessage[BUF_SIZE];
char newMessage[BUF_SIZE];
bool newMessageAvailable = false;

void setup()
{
  // Enable the next line to clear the message from eeprom.
  // EEPROM.write(0,1);
  
  mySerial.begin(9600); 
  delay(500);
  
  // The next line configures the BT-04 (BT-06) Module to NOT report connection status. 
  mySerial.write("\r\nAT+ENABLEIND0\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  // change the name of the BT-04 (BT-06) device, this will not work for HC-06
  mySerial.write("AT+NAMELichtkrant01\r\n"); 
  delay(100);
  ClearRXbuffer();
  
  LK.begin();
  LK.displayClear();
  LK.displaySuspend(false);
  LK.displayText(curMessage, scrollAlign, scrollSpeed, scrollPause, scrollEffect, scrollEffect);  

  // Get the last message from EEPROM
  getMessageFromEeprom();
}


void loop()
{  
  readSerial();
  if (LK.displayAnimate())
  {
    if (newMessageAvailable)
    {
      strcpy(curMessage, newMessage);
      newMessageAvailable = false;
      storeMessageInEeprom();
    }
    LK.displayReset();
  }
}


  
void readSerial(void) {
  static char *cp = newMessage;
  while (mySerial.available())  
  {
    *cp = (char)mySerial.read();
    if ( (*cp == '\r') || (*cp == '\n') || (cp - newMessage >= BUF_SIZE-2)) // end of message character or full buffer
    {
      *cp = '\0'; // end the string   
      cp = newMessage;
      newMessageAvailable = true;
      mySerial.print("Nieuwe Boodschap = ");
      mySerial.println(newMessage);
      ClearRXbuffer();
    }
    else  // move char pointer to next position
      cp++;
  }
}


void storeMessageInEeprom(){
  // Store the message in EEPROM
  EEPROM.write(0,251);
  int i=0;
  char c=curMessage[i];
  while (c !=0){
    EEPROM.write(i+1,c);
    i++;
    c=curMessage[i];
    }
    EEPROM.write(i+1,0);
}

void getMessageFromEeprom(){
  if (EEPROM.read(0)!=251){
    strcpy(curMessage, "Hello! Please Send new message over bluetooth");
    newMessage[0] = '\0';
    } else {      
      int i=0;
      char c = EEPROM.read(i+1);
      while (c!=0){
        curMessage[i++]=c;
        c = EEPROM.read(i+1);
        }
        curMessage[i] = '\0';
        newMessageAvailable=false;         
    }
}

void ClearRXbuffer(){
  while (mySerial.available()){
    char c=mySerial.read(); 
    delay(5);
    } 
}

If all is well (and why not?) you will now see the message “Hello, please send a new message over bluetooth”. So it's high time to install the Android App on your phone and send a new message via Bluetooth!

The Android App:

To change the text on the news ticker we need a Bluetooth terminal program, for example the Serial Bluetooth Terminal from Kai Morich, via the AppStore.

SerialBluetoothTerminal

The operation of the App is fairly self-explanatory, but in the video I show it step by step.

bluetooth terminal

Attention: Apple's iOS cannot connect to the used bluetooth module, so this only works with Android devices.

watch the video

Are there still ambiguities? You can take a closer look at everything in this video.

Posted by Bart Venneker Website | Youtube Bart Venneker is an electronics hobbyist and makes educational videos about electronics, Arduino and 3d printers.

Comments

Ad Laat

Unfortunately, the adjustments cannot be found in the library, which means that the ticker does not work, which is a shame! Could a different version have been used? Greetings, Ad de Laat

Placed on 19 November 2023

