Always on time with the DS1307 and DS3231 REAL time clock modules

Placed on 2016-07-16

REAL time clock modules

REAL time clock versions

The REAL time clock series contains many different type numbers, all with comparable functionality. In this series only 2 versions are 'mainstream', namely the DS1307 and the DS3231. These chips both have the option to connect a battery and have a sqw output pin, with which the controller can receive a clock pulse of (1Hz, 1.024kHz, 4.096kHz, 8.192kHz). Both ICs also have a One-Wire interface, which makes it possible to connect them over I²to address C.

DS1302 Real Time Clock Module - SPIThe DS1302 Real Time Clock Module has an SPI interface through which it can tell the time. In stock € 1,85

Real time clock module DS3231Real time clock module with the DS3231 chip. This module ensures that the Arduino knows the exact time at all times. By connecting the Arduino to the ´qw´ pin, it is possible to generate an interrupt every second with which sensor values or a display can be addressed. In stock € 3,95

Connecting the RTC module to the Arduino UNO

The RTC modules come in different shapes and sizes, but the connection to the Arduino is the same for all modules. The module must in any case be powered with 5V, furthermore the I2C interface will have to be connected to the SDA (Serial data) SCL (Serial clock) pins of the Arduino (these are pins A4 and A5 on the Arduino UNO). Furthermore, the SQW output can be connected to any pin of the Arduino to receive a clock pulse from the RTC.

DS1307 connection Arduino UNO

BC Code

The numerical values in the RTC chips are stored in BCD format. BCD code is easier to use than decimal numbers on a hardware level, but these codes are not very useful in software. The numbers to and from the chip must therefore be encoded and decoded so that the controller and RTC understand each other.

// Convert decimal to BCD
byte decToBcd(byte val)
{
  return( (val/10*16) + (val%10) );
}
//Convert BCD to decimal
byte bcdToDec(byte val)
{
  return( (val/16*10) + (val%16) );
}

Write the current time to the RTC

The time only needs to be written to the RTC once when it is connected to the battery. The RTC itself keeps time and continues counting, even when it is not connected to the controller.

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setDS3231time(
    byte second, 
    byte minute, 
    byte hour, 
    byte dayOfWeek, 
    byte dayOfMonth, 
    byte month, 
    byte year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //set next input to start at the seconds register
  Wire.write(0); 
  
  //set seconds
  Wire.write(decToBcd(second)); 
  //set minutes
  Wire.write(decToBcd(minute)); 
  //set hours
  Wire.write(decToBcd(hour)); 
  //set day of week (1=Sunday, 7=Saturday)
  Wire.write(decToBcd(dayOfWeek));  
  //set date (1 to 31)
  Wire.write(decToBcd(dayOfMonth)); 
  //set month
  Wire.write(decToBcd(month));
  //set year 20(0 to 99)
  Wire.write(decToBcd(year)); 
    
  Wire.endTransmission();
}

Hard drive clock

De tijd van de RTC lezen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void readDS3231time(
    byte *second,
	byte *minute,
	byte *hour,
	byte *dayOfWeek,
	byte *dayOfMonth,
	byte *month,
	byte *year)
{
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  //set DS3231 register pointer to 00h
  Wire.write(0); 
  Wire.endTransmission();
      
  //request seven bytes of data from DS3231
  Wire.requestFrom(DS3231_I2C_ADDRESS, 7);
  *second = bcdToDec(Wire.read() & 0x7f);
  *minute = bcdToDec(Wire.read());
  *hour = bcdToDec(Wire.read() & 0x3f);
  *dayOfWeek = bcdToDec(Wire.read());
  *dayOfMonth = bcdToDec(Wire.read());
  *month = bcdToDec(Wire.read());
  *year = bcdToDec(Wire.read());
}

Show the time

With these functions together, the time can be determined by the Arduino . With the function below this data is written to the serial monitor, but the possibilities for displaying the time are endless.

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  //set the initial time (only once, not every startup)
  //seconds, minutes, hours, dayofweek, day, month, year
  //11:00:00, Saturday, 2016-07-16
  setDS3231time(00,00,11,7,16,7,16);
}

void displayTime()
{
  byte second, minute, hour; 
  byte dayOfWeek, dayOfMonth, month, year;
  
  //retrieve data
  readDS3231time(&second, &minute, &hour, &dayOfWeek, 				     &dayOfMonth, &month, &year);
    
  //Hour
  Serial.print(hour, DEC);
  Serial.print(":");
  //Minute (+0 if needed)
  if (minute<10)
  {
    Serial.print("0");
  }
  Serial.print(minute, DEC);
  Serial.print(":");
  //Second (+0 if needed)
  if (second<10)
  {
    Serial.print("0");
  }
  Serial.print(second, DEC);
  Serial.print(" ");
    
  //Day
  Serial.print(dayOfMonth, DEC);
  Serial.print("/");
  //Month
  Serial.print(month, DEC);
  Serial.print("/");
  //Year
  Serial.print(year, DEC);
}


void loop()
{
  displayTime(); 
  delay(1000);
}

SQW frequentie instellen

#include "Wire.h"
#define DS3231_I2C_ADDRESS 0x68

void setup()
{
  Wire.begin();
  Serial.begin(9600);
  
  Wire.beginTransmission(DS3231_I2C_ADDRESS);
  
  //move pointer to SQW address
  Wire.write(0x07); 
 
  //set output clock speed
  //0x00 = Off
  //0x10 = 1Hz
  //0x11 = 4.096Hz
  //0x12 = 8.192Hz
  //0x13 = 32.768Hz
  Wire.write(0x10);
 
  Wire.endTransmission();  
}

With this code a complete clock can be built, which can display the time. This can be done on a 7-segment display, as an analog clock, with smoke signals or it can even be spoken when requested. In addition, the time can also be used in home automation / home automation, coffee maker switches on in the morning at 8 am, the microwave at 5.15 pm in the evening and the curtains close at 7.01:05 pm. Everything is possible.

Posted by Robin Blok Website I am interested in electronics, programming and especially the combination between them. For Opencircuit I write blogs in which I explain how electronics and modules work.